Instructions SQL embarquées

Exécution d’instructions SQL

La plupart des instructions SQL sont transmises telles quelles à la base de données, après remplacement des variables hôtes par des marqueurs de paramètres : INSERT, UPDATE, DELETE, instructions DDL (CREATE, DROP…), SAVEPOINT, etc. Le précompilateur ne vérifie pas la syntaxe SQL : les erreurs sont signalées par la base de données à l’exécution.

           EXEC SQL
               INSERT INTO EMP (EMPNO, ENAME, SAL, DEPTNO)
               VALUES (:EMP-NUMBER, :EMP-NAME, :SALARY, :DEPT-NO)
           END-EXEC.

           EXEC SQL
               UPDATE EMP SET SAL = :SALARY WHERE EMPNO = :EMP-NUMBER
           END-EXEC.

           EXEC SQL
               DELETE FROM EMP WHERE DEPTNO = :DEPT-NO
           END-EXEC.

Après un INSERT, un UPDATE ou un DELETE, le champ SQLERRD(3) de la SQLCA contient le nombre de lignes traitées.

NoteÀ vérifier

SQLERRD(3) pour chaque pilote.

Requêtes mono-ligne : SELECT INTO

Un SELECT qui renvoie au plus une ligne stocke directement son résultat dans des variables hôtes :

           EXEC SQL
               SELECT ENAME, SAL, COMM
                 INTO :EMP-NAME, :SALARY, :COMM:COMM-IND
                 FROM EMP
                WHERE EMPNO = :EMP-NUMBER
           END-EXEC.

Si aucune ligne n’est trouvée, SQLCODE contient le code « aucun enregistrement » (100 par défaut, voir La condition « aucun enregistrement »). Si plusieurs lignes sont trouvées, une erreur est renvoyée.

Curseurs

Une requête qui renvoie plusieurs lignes est traitée avec un curseur :

  1. déclarer le curseur (DECLARE), avec sa requête ;
  2. l’ouvrir (OPEN) : la requête est exécutée ;
  3. lire les lignes une par une (FETCH), jusqu’à la condition « aucun enregistrement » ;
  4. le fermer (CLOSE).
           EXEC SQL
               DECLARE EMPCUR CURSOR FOR
                 SELECT ENAME, SAL FROM EMP
                  WHERE DEPTNO = :DEPT-NO
                  ORDER BY ENAME
           END-EXEC.

           EXEC SQL OPEN EMPCUR END-EXEC.
           PERFORM UNTIL SQLCODE NOT = 0
               EXEC SQL
                   FETCH EMPCUR INTO :EMP-NAME, :SALARY
               END-EXEC
               IF SQLCODE = 0
                   DISPLAY EMP-NAME " " SALARY
               END-IF
           END-PERFORM.
           EXEC SQL CLOSE EMPCUR END-EXEC.

Les variables hôtes d’entrée de la requête (:DEPT-NO) sont lues à l’ouverture du curseur.

  • DECLARE CURSOR peut apparaître dans la DATA DIVISION ou dans la PROCEDURE DIVISION. Ce n’est pas une instruction exécutable : elle ne modifie pas SQLCODE.

  • FETCH n’accepte pas la clause AT : le curseur est utilisé sur la connexion où il a été déclaré.

  • Un curseur déclaré WITH HOLD reste ouvert après un COMMIT :

             EXEC SQL
                 DECLARE C1 CURSOR WITH HOLD FOR SELECT ...
             END-EXEC.
Important

Avec les curseurs natifs de PostgreSQL, les curseurs doivent être utilisés à l’intérieur d’une transaction : voir Autocommit.

Curseurs modifiables

La ligne courante d’un curseur déclaré FOR UPDATE peut être modifiée ou supprimée avec WHERE CURRENT OF :

           EXEC SQL
               DECLARE C2 CURSOR FOR
                 SELECT ENAME, SAL FROM EMP FOR UPDATE
           END-EXEC.
           ...
           EXEC SQL
               UPDATE EMP SET SAL = SAL * 1.1 WHERE CURRENT OF C2
           END-EXEC.

Leur support dépend de la base de données :

  • Oracle et PostgreSQL (avec les curseurs natifs) les supportent directement.
  • MySQL et SQLite les émulent, avec l’option updatable_cursors ; la table doit avoir une clé unique.
  • Avec ODBC, cela dépend du pilote ODBC.

Curseurs sur des instructions préparées

Un curseur peut aussi être déclaré sur une instruction préparée (voir SQL dynamique) :

           EXEC SQL DECLARE C3 CURSOR FOR STMT1 END-EXEC.

Transactions

Voir Connexions et transactions.

Autres instructions

NoteÀ compléter

EXEC SQL IGNORE, CALL / procédures stockées, LOCK TABLE, SET TRANSACTION, DECLARE TABLE.